From: Simen Heggestøyl <simenheg@gmail.com>
Date: Sun, 26 May 2019 09:11:23 +0000 (+0200)
Subject: Use lexical-binding in paren.el and add tests
X-Git-Tag: emacs-27.0.90~2785
X-Git-Url: http://git.eshelyaron.com/gitweb/?a=commitdiff_plain;h=a51ab2f357af49f67feaa6e9484fcca2c91f5cb4;p=emacs.git

Use lexical-binding in paren.el and add tests

* lisp/paren.el: Use lexical-binding.
(show-paren--default): Use imperative form in doc-string.

* test/lisp/paren-tests.el: New file with tests for paren.el.
---

diff --git a/lisp/paren.el b/lisp/paren.el
index 13908d46eef..c7d782a8a1d 100644
--- a/lisp/paren.el
+++ b/lisp/paren.el
@@ -1,4 +1,4 @@
-;;; paren.el --- highlight matching paren
+;;; paren.el --- highlight matching paren  -*- lexical-binding:t -*-
 
 ;; Copyright (C) 1993, 1996, 2001-2019 Free Software Foundation, Inc.
 
@@ -173,7 +173,7 @@ if there's no opener/closer near point, or a list of the form
 Where HERE-BEG..HERE-END is expected to be near point.")
 
 (defun show-paren--default ()
-  "Finds the opener/closer near point and its match.
+  "Find the opener/closer near point and its match.
 
 It is the default value of `show-paren-data-function'."
   (let* ((temp (show-paren--locate-near-paren))
diff --git a/test/lisp/paren-tests.el b/test/lisp/paren-tests.el
new file mode 100644
index 00000000000..5aaea8a7d94
--- /dev/null
+++ b/test/lisp/paren-tests.el
@@ -0,0 +1,121 @@
+;;; paren-tests.el --- Tests for paren.el  -*- lexical-binding: t; -*-
+
+;; Copyright (C) 2019 Free Software Foundation, Inc.
+
+;; Author: Simen Heggestøyl <simenheg@gmail.com>
+;; Keywords:
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;;
+
+;;; Code:
+
+(require 'ert)
+(require 'paren)
+
+(ert-deftest paren-tests-unescaped-p ()
+  (with-temp-buffer
+    (insert "(insert)")
+    (backward-char)
+    (should (show-paren--unescaped-p (point)))
+    (insert "\\")
+    (should-not (show-paren--unescaped-p (point)))))
+
+(ert-deftest paren-tests-categorize-paren ()
+  (with-temp-buffer
+    (insert "(insert)")
+    (backward-char)
+    (should (equal (show-paren--categorize-paren (point))
+                   (cons -1 (+ (point) 1))))
+    (goto-char (point-min))
+    (should (equal (show-paren--categorize-paren (point))
+                   (cons 1 (point))))))
+
+(ert-deftest paren-tests-locate-near-paren ()
+  (with-temp-buffer
+    (let ((show-paren-when-point-inside-paren nil)
+          (show-paren-when-point-in-periphery nil))
+      (insert "(insert)")
+      (should (equal (show-paren--locate-near-paren)
+                     (cons -1 (point))))
+      (backward-char)
+      (should-not (show-paren--locate-near-paren))
+      (goto-char (point-min))
+      (should (equal (show-paren--locate-near-paren)
+                     (cons 1 (point-min))))
+      (forward-char)
+      (should-not (show-paren--locate-near-paren)))))
+
+(ert-deftest paren-tests-locate-near-paren-inside ()
+  (with-temp-buffer
+    (let ((show-paren-when-point-inside-paren t)
+          (show-paren-when-point-in-periphery nil))
+      (insert "(insert)")
+      (should (equal (show-paren--locate-near-paren)
+                     (cons -1 (point))))
+      (backward-char)
+      (should (equal (show-paren--locate-near-paren)
+                     (cons -1 (+ (point) 1))))
+      (goto-char (point-min))
+      (should (equal (show-paren--locate-near-paren)
+                     (cons 1 (point-min))))
+      (forward-char)
+      (should (equal (show-paren--locate-near-paren)
+                     (cons 1 (point-min)))))))
+
+(ert-deftest paren-tests-locate-near-paren-in-periphery ()
+  (with-temp-buffer
+    (let ((show-paren-when-point-inside-paren nil)
+          (show-paren-when-point-in-periphery t))
+      (insert " (insert) ")
+      (should (equal (show-paren--locate-near-paren)
+                     (cons -1 (- (point) 1))))
+      (backward-char 2)
+      (should-not (show-paren--locate-near-paren))
+      (goto-char (point-min))
+      (should (equal (show-paren--locate-near-paren)
+                     (cons 1 (+ (point) 1))))
+      (forward-char)
+      (should (equal (show-paren--locate-near-paren)
+                     (cons 1 (point))))
+      (forward-char)
+      (should-not (show-paren--locate-near-paren)))))
+
+(ert-deftest paren-tests-default ()
+  (with-temp-buffer
+    (insert "(insert")
+    (goto-char (point-min))
+    (should (equal (show-paren--default)
+                   (list (point) (+ (point) 1)
+                         nil nil
+                         t)))
+    (goto-char (point-max))
+    (insert ")")
+    (should (equal (show-paren--default)
+                   (list (- (point) 1) (point)
+                         (point-min) (+ (point-min) 1)
+                         nil)))
+    (goto-char (point-min))
+    (should (equal (show-paren--default)
+                   (list (point) (+ (point) 1)
+                         (- (point-max) 1) (point-max)
+                         nil)))))
+
+(provide 'paren-tests)
+;;; paren-tests.el ends here