From: Juri Linkov <juri@linkov.net>
Date: Thu, 2 Dec 2021 18:12:05 +0000 (+0200)
Subject: * lisp/tab-bar.el (tab-bar-close-other-tabs): Fix regression.
X-Git-Tag: emacs-28.0.91~104
X-Git-Url: http://git.eshelyaron.com/gitweb/?a=commitdiff_plain;h=0a50ad11db;p=emacs.git

* lisp/tab-bar.el (tab-bar-close-other-tabs): Fix regression.

* test/lisp/tab-bar-tests.el: New file.
(tab-bar-tests-close-other-tabs-with-arg): Test for regression
that closed the selected tab after selecting it.
---

diff --git a/lisp/tab-bar.el b/lisp/tab-bar.el
index ca1087e827d..cfd766d5495 100644
--- a/lisp/tab-bar.el
+++ b/lisp/tab-bar.el
@@ -1572,18 +1572,17 @@ happens interactively)."
   (let* ((tabs (funcall tab-bar-tabs-function))
          (current-index (tab-bar--current-tab-index tabs))
          (keep-index (if (integerp tab-number)
-                         (1- (max 0 (min tab-number (length tabs))))
+                         (1- (max 1 (min tab-number (length tabs))))
                        current-index))
-         (keep-tab (nth keep-index tabs))
          (index 0))
 
-    (when keep-tab
+    (when (nth keep-index tabs)
       (unless (eq keep-index current-index)
         (tab-bar-select-tab (1+ keep-index))
         (setq tabs (funcall tab-bar-tabs-function)))
 
       (dolist (tab tabs)
-        (unless (or (eq tab keep-tab)
+        (unless (or (eq index keep-index)
                     (run-hook-with-args-until-success
                      'tab-bar-tab-prevent-close-functions tab
                      ;; `last-tab-p' logically can't ever be true
diff --git a/test/lisp/tab-bar-tests.el b/test/lisp/tab-bar-tests.el
new file mode 100644
index 00000000000..7212ce89167
--- /dev/null
+++ b/test/lisp/tab-bar-tests.el
@@ -0,0 +1,51 @@
+;;; tab-bar-tests.el --- Tests for tab-bar.el          -*- lexical-binding: t; -*-
+
+;; Copyright (C) 2021 Free Software Foundation, Inc.
+
+;; Author: Juri Linkov <juri@linkov.net>
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
+
+;;; Code:
+
+(require 'ert)
+
+(defun tab-bar-tests-close-other-tabs (arg)
+  (tab-bar-tabs-set nil)
+  (tab-rename "1")
+  (tab-new) (tab-rename "2") ;; (tab-switch "2")
+  (tab-new) (tab-rename "3") ;; (tab-switch "3")
+  (should (eq (length (tab-bar-tabs)) 3))
+  (should (equal (alist-get 'name (tab-bar--current-tab-find)) "3"))
+  (tab-bar-close-other-tabs arg)
+  (should (equal (alist-get 'name (tab-bar--current-tab-find))
+                 (if arg (number-to-string (max 1 (min arg 3))) "3")))
+  (should (eq (length (tab-bar-tabs)) 1))
+  (should (eq (length tab-bar-closed-tabs) 2))
+  (tab-undo)
+  (tab-undo)
+  (should (equal (tab-undo) "No more closed tabs to undo"))
+  (should (eq (length (tab-bar-tabs)) 3))
+  (should (eq (length tab-bar-closed-tabs) 0)))
+
+(ert-deftest tab-bar-tests-close-other-tabs-default ()
+  (tab-bar-tests-close-other-tabs nil))
+
+(ert-deftest tab-bar-tests-close-other-tabs-with-arg ()
+  (dotimes (i 5) (tab-bar-tests-close-other-tabs i)))
+
+(provide 'tab-bar-tests)
+;;; tab-bar-tests.el ends here