Use lexical-binding in page.el and add tests

* lisp/textmodes/page.el: Use lexical-binding.
(forward-page): Replace `(if x nil y)' with `(unless x y)'.

* test/lisp/textmodes/page-tests.el: New file with tests for page.el.

diff --git a/lisp/textmodes/page.el b/lisp/textmodes/page.el
index 220ef2d7fd6768c4af25e4ddabcf271cfae0d0e0..2b0cea4c643e3b5fc1c355eb2532762f93363098 100644 (file)
--- a/lisp/textmodes/page.el
+++ b/lisp/textmodes/page.el
@@ -1,4 +1,4 @@
-;;; page.el --- page motion commands for Emacs
+;;; page.el --- page motion commands for Emacs  -*- lexical-binding: t; -*-
 
 ;; Copyright (C) 1985, 2001-2019 Free Software Foundation, Inc.
 
@@ -38,8 +38,7 @@ A page boundary is any line whose beginning matches the regexp
     ;; In case the page-delimiter matches the null string,
     ;; don't find a match without moving.
     (if (bolp) (forward-char 1))
-    (if (re-search-forward page-delimiter nil t)
-       nil
+    (unless (re-search-forward page-delimiter nil t)
       (goto-char (point-max)))
     (setq count (1- count)))
   (while (and (< count 0) (not (bobp)))

diff --git a/test/lisp/textmodes/page-tests.el b/test/lisp/textmodes/page-tests.el
new file mode 100644 (file)
index 0000000..0834d65
--- /dev/null
+++ b/test/lisp/textmodes/page-tests.el
@@ -0,0 +1,86 @@
+;;; page-tests.el --- Tests for page.el  -*- lexical-binding: t; -*-
+
+;; Copyright (C) 2019 Free Software Foundation, Inc.
+
+;; Author: Simen Heggestøyl <simenheg@gmail.com>
+;; Keywords:
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;;
+
+;;; Code:
+
+(require 'ert)
+(require 'page)
+
+(ert-deftest page-tests-forward-page ()
+  (with-temp-buffer
+    (insert "foo\n\f\nbar\n\f\nbaz")
+    (forward-page -1)
+    (should (looking-at-p "\nbaz"))
+    (forward-page -2)
+    (should (= (point) (point-min)))
+    (forward-page 1)
+    (should (looking-at-p "\nbar"))
+    (forward-page)
+    (should (looking-at-p "\nbaz"))
+    (forward-page 1)
+    (should (= (point) (point-max)))))
+
+(ert-deftest page-tests-backward-page ()
+  (with-temp-buffer
+    (insert "foo\n\f\nbar\n\f\nbaz")
+    (backward-page 1)
+    (should (looking-at-p "\nbaz"))
+    (backward-page)
+    (should (looking-at-p "\nbar"))
+    (backward-page 1)
+    (should (= (point) (point-min)))
+    (backward-page -1)
+    (should (looking-at-p "\nbar"))
+    (backward-page -2)
+    (should (= (point) (point-max)))))
+
+(defun page-tests--region-string ()
+  "Return the contents of the region as a string."
+  (buffer-substring (region-beginning) (region-end)))
+
+(ert-deftest page-tests-mark-page ()
+  (with-temp-buffer
+    (insert "foo\n\f\nbar\n\f\nbaz")
+    (mark-page)
+    (should (equal (page-tests--region-string) "\nbaz"))
+    (mark-page -2)
+    (should (equal (page-tests--region-string) "foo\n\f"))
+    (mark-page 1)
+    (should (equal (page-tests--region-string) "\nbar\n\f"))))
+
+(ert-deftest page-tests-narrow-to-page ()
+  (with-temp-buffer
+    (insert "foo\n\f\nbar\n\f\nbaz")
+    (goto-char (point-min))
+    (narrow-to-page)
+    (should (equal (buffer-string) "foo\n"))
+    (narrow-to-page 2)
+    (should (equal (buffer-string) "baz"))
+    (narrow-to-page -1)
+    (should (equal (buffer-string) "bar\n"))))
+
+(provide 'page-tests)
+;;; page-tests.el ends here